Symbol.pm

package Symbol;

use strict;
use warnings;

require Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw(gensym ungensym qualify qualify_to_ref);
our @EXPORT_OK = qw(delete_package geniosym);

our $VERSION = '1.09';

my $genpkg = "Symbol::";
my $genseq = 0;

my %global = map {$_ => 1} qw(ARGV ARGVOUT ENV INC SIG STDERR STDIN STDOUT);

#
# Note that we never _copy_ the glob; we just make a ref to it.
# If we did copy it, then SVf_FAKE would be set on the copy, and
# glob-specific behaviors (e.g. C<*$ref = \&func>) wouldn't work.
#
sub gensym () {
    my $name = "GEN" . $genseq++;
    no strict 'refs';
    my $ref = \*{$genpkg . $name};
    delete $$genpkg{$name};
    $ref;
}

sub geniosym () {
    my $sym = gensym();
    # force the IO slot to be filled
    select(select $sym);
    *$sym{IO};
}

sub ungensym ($) {}

sub qualify ($;$) {
    my ($name) = @_;
    if (!ref($name) && index($name, '::') == -1 && index($name, "'") == -1) {
	my $pkg;
	# Global names: special character, "^xyz", or other. 
	if ($name =~ /^(([^a-z])|(\^[a-z_]+))\z/i || $global{$name}) {
	    # RGS 2001-11-05 : translate leading ^X to control-char
	    $name =~ s/^\^([a-z_])/'qq(\c'.$1.')'/eei;
	    $pkg = "main";
	}
	else {
	    $pkg = (@_ > 1) ? $_[1] : caller;
	}
	$name = $pkg . "::" . $name;
    }
    $name;
}

sub qualify_to_ref ($;$) {
    no strict 'refs';
    return \*{ qualify $_[0], @_ > 1 ? $_[1] : caller };
}

#
# of Safe.pm lineage
#
sub delete_package ($) {
    my $pkg = shift;

# expand to full symbol table name if needed

unless ($pkg =~ /^main::.*::$/) {
        $pkg = "main$pkg"	if	$pkg =~ /^::/;
        $pkg = "main::$pkg"	unless	$pkg =~ /^main::/;
        $pkg .= '::'		unless	$pkg =~ /::$/;
    }

my($stem, $leaf) = $pkg =~ m/(.*::)(\w+::)$/;
    no strict 'refs';
    my $stem_symtab = *{$stem}{HASH};
    return unless defined $stem_symtab and exists $stem_symtab->{$leaf};

# free all the symbols in the package

my $leaf_symtab = *{$stem_symtab->{$leaf}}{HASH};
    foreach my $name (keys %$leaf_symtab) {
        undef *{$pkg . $name};
    }
    use strict 'refs';

# delete the symbol table

%$leaf_symtab = ();
    delete $stem_symtab->{$leaf};
}

docroot: /var/www/469ed2f6-4d4b-4a8a-9f5e-ee4ef04d3bc8/public_html

curdir: /usr/lib/x86_64-linux-gnu/perl-base

	.	4096
	..	69632
X	AutoLoader.pm	5487
	Carp	4096
X	Carp.pm	25399
X	Config.pm	3278
X	Config_git.pl	409
X	Config_heavy.pl	58427
X	Cwd.pm	17356
X	DynaLoader.pm	11266
X	Errno.pm	4913
	Exporter	4096
X	Exporter.pm	2336
X	Fcntl.pm	2100
	File	4096
X	FileHandle.pm	2111
	Getopt	4096
	Hash	4096
	IO	4096
X	IO.pm	469
	IPC	4096
	List	4096
X	POSIX.pm	20442
	Scalar	4096
X	SelectSaver.pm	344
X	Socket.pm	13865
X	Symbol.pm	2205
	Text	4096
	Tie	4096
X	XSLoader.pm	4115
X	attributes.pm	3069
	auto	4096
X	base.pm	8912
X	builtin.pm	210
X	bytes.pm	489
X	bytes_heavy.pl	758
X	constant.pm	5737
X	feature.pm	7891
X	fields.pm	5008
X	integer.pm	172
X	lib.pm	2284
X	locale.pm	3451
X	overload.pm	4857
X	overloading.pm	964
X	parent.pm	460
X	re.pm	9556
X	strict.pm	1606
	unicore	4096
X	utf8.pm	341
X	vars.pm	1148
	warnings	4096
X	warnings.pm	30504